; This script sends messages in the specified directory to an 
; alphanumeric pager using TAP manual mode.
;
; The first eight characters of the file should be the PIN, for
; example 555-1212.  Carriage returns may appear as boxes on the
; pager, so generate files with no CRs or LFs.
;
; The files can be of unlimited size.  Here is an example input file:
; 555-1212FR:Tom SB:Hello MES:See you later.
;
; Every file with no extension in the directory will be processed.

PROC setup                          
 set baudrate 1200
 set databits 7
 set stopbits 1
endproc

PROC sendit
 WAITFOR "RETURN"
 while forever
  string file1="c:\c2\mhs\mail\pages\*."  ;dir w/ files to send	
  findfirst file1
  string path="c:\c2\mhs\mail\pages\"
  strcat path $filename			  ;complete file name
  if found
   string PIN				  ;first 8 chars of file
   string PT1				  ;230 chars out of file
   fopen 0 path "rt"
   fread 0 PIN 8 n1
   while not eof 0 
    transmit PIN
    TRANSMIT "^M"
    WAITFOR "RETURN"
    integer count
    for count = 1 upto 230		  ;send in blocks of 230	
     fread 0 PT1 1 n2
     transmit PT1 
    endfor
    transmit "^M"
    WAITFOR "RETURN"
    pause 3			;prevents pages from arriving out of order
   endwhile			; end of while not eof 0
   fclose 0
   delete path
  else
   call done
  endif				;if a file was found
 endwhile			;end while forever
endproc

PROC logon
 TRANSMIT "AT&FQ0E1V1TDS1^M"    ;S1 is the pager service number in my modem's              
 WAITFOR "CONNECT"		;NVRAM.  Change the end to the right number
 WAITFOR "ID"
 TRANSMIT "M^M"
endproc

PROC done
 HANGUP
 quit
endproc

PROC MAIN
 call setup
 string file1="c:\c2\mhs\mail\pages\*."   ;Dir to hold the files
 findfirst file1
 if found
  call logon
  call sendit
  call done
 else 
  call done
 endif
endproc