;===============================================================
; CentreDialog
;
; Moves a nominated dialog box ID to the centre of Procomm.
;===============================================================
;
;The dialogbox style "3" ("centred with respect to parent") doesn't work
;in multiple-monitor PCs where Procomm's NOT on the primary display.
;
;Call this proc with the dialogID of a VISIBLE dialogbox and it'll
;centre the box with respect to Procomm.
;
;There are a few potential weaknesses:
;"Wincoord" reports a width and height of 0:
;1) if the box is not visible on the screen.
;2) if the box straddles the two screens (depends on where).
;
;This proc is written to be "generic", centring any box based upon
;its dialogID. (Box dimensions can't be variables, they must be
;constants, and can't be "passed"). The results can be improved by
;hard-coding the size of the dialogbox you're wanting to centre.
;
;The "usermsg" commands are for debugging and testing the theory.


proc CentreDialog

param integer whichBox

integer handle
integer nLeft, nTop
integer nWidth, nHeight
integer BoxLeft, boxTop
integer BoxHeight, BoxWidth

wincoord $PWMAINWIN nLeft nTop nWidth nHeight   ;Get Procomm's size and position.

usermsg "Procomm's position: L: %d T: %d W: %d H: %d" nLeft nTop nWidth nHeight
nHeight = nHeight / 2      ;Halve the size of Procomm
nWidth = nWidth / 2
nLeft = nLeft + nWidth     ;This gives us the dead centre of the host box.
nTop = nTop + nHeight
;usermsg "Dead Centre L: %d T: %d W: %d H: %d" nLeft nTop nWidth nHeight

dlgwin whichBox Handle              ;ID the dialogbox in question
wincoord Handle BoxLeft BoxTop BoxWidth BoxHeight  ;Get the dialogbox's width & height

;usermsg "Box details L: %d T: %d W: %d H: %d" BoxLeft BoxTop BoxWidth BoxHeight

boxHeight = boxHeight / 2  ;Halve the size of the new box
boxWidth = BoxWidth / 2

nLeft = nLeft - BoxWidth   ;These are the new location for the dialog box.
nTop = nTop - BoxHeight

winmove Handle nLeft nTop  ;Move it to its new location
dlgshow WhichBox     ; ... and show it off!

;usermsg "L: %d T: %d W: %d H: %d" nLeft nTop nWidth nHeight

endproc


;===============================================================